home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Generous Efforts of Many
/
gemcd.zip
/
GEM.CD.A.po
/
FEATURES:BEAGLE
/
BEAGLE.BAG.SHK
/
BEAGLE.BAG
/
HANG PERSON.bas
< prev
next >
Wrap
BASIC Source File
|
2000-01-01
|
8KB
|
131 lines
90 REM <CTRL-M><CTRL-M>HANG PERSON<CTRL-M>BY BERT KERSEY<CTRL-M>BEAGLE BROS<CTRL-M>
100 GOSUB 2580: ONERR GOTO 63900
105 FOR I = 1 TO 150: READ X$(I): NEXT
110 FOR I = 1 TO 150:N(I) = 0: NEXT
130 TEXT : HOME : VTAB 5: PRINT "H A N G ";: GOSUB 2540: PRINT " P E R S O N !": PRINT "- - - - - - - - - -": PRINT : GOSUB 2540
140 PRINT "HIT <RETURN> ONLY";: INVERSE : HTAB 6: PRINT "RETURN": NORMAL : PRINT " TO PLAY AGAINST": PRINT " THE COMPUTER, OR...": PRINT : PRINT
150 GOSUB 2540: FOR I = 1 TO 400: NEXT
160 FOR I = 1 TO 150: IF N(I) = 0 THEN 170
162 NEXT : GOTO 110
170 VTAB 12
180 PRINT "TYPE YOUR SECRET WORD(S): ______________ THEN HIT <RETURN>.": PRINT : GOSUB 2540
190 VTAB 20: PRINT "TYPE LETTERS + SPACES ONLY, 14 MAXIMUM. ": GOSUB 2540: PRINT " S <RETURN> TURNS MUSIC ON.<CTRL-H><CTRL-H><CTRL-H>";: IF MU = 771 THEN PRINT "OFF.";
192 PRINT : PRINT " Q <RETURN> QUITS GAME."
195 VTAB 12: HTAB 27: POKE QQ,0: INPUT "";W$
196 IF W$ = "S" THEN MU = MU +(MU = 770) -(MU = 771): GOTO 130
197 IF W$ = "Q" THEN 63900
200 IF NOT LEN(W$) THEN GOSUB 9000
210 FOR I = 1 TO LEN(W$):J = ASC( MID$ (W$,I,1)): IF (J < ASC("A") AND J < >32) OR (J > ASC("Z")) THEN 130
212 NEXT
220 IF LEN(W$) >14 THEN 130
222 HOME : GR
230 REM <CTRL-J><CTRL-J>START GAME<CTRL-J>
240 VTAB 21: PRINT "SECRET WORD:": PRINT : PRINT "TYPE A LETTER."
260 X = 18:Z = 12
270 FOR J = 1 TO LEN(W$):A(J) = 0: IF MID$ (W$,J,1) = " " THEN A(J) = 1: IF MID$ (W$,J,1) = " " THEN P = P +1
272 NEXT
280 GOSUB 700
290 FOR J = 1 TO LEN(W$): VTAB 22: HTAB X -7 +2 *J: PRINT "-";: GOSUB 2540: NEXT
300 FOR J = 1 TO LEN(W$): IF MID$ (W$,J,1) < >" " THEN 320
310 VTAB 22: HTAB (2 *J) -7 +X: PRINT " "
320 NEXT
330 L = 0
340 REM <CTRL-J><CTRL-J>WORD FINISHED?<CTRL-J>
350 FOR J = 1 TO LEN(W$): IF A(J) < >1 THEN 460
352 NEXT
360 REM <CTRL-J><CTRL-J>WORD FINISHED<CTRL-J>
370 VTAB 24: HTAB 1: CALL -868: HTAB 1: INVERSE :W$ = " YOU GOT IT!! ": FOR I = 1 TO 14: PRINT MID$ (W$,I,1);
380 POKE 0, INT( RND(1) *200) +20
390 POKE 1,44
400 CALL MU
410 NEXT
420 POKE 1,150
430 CALL MU
440 NORMAL : VTAB 21: HTAB 1: PRINT "<RETURN> ";: FLASH : HTAB 2: PRINT "RETURN";: NORMAL : VTAB 21: HTAB 2: GET W$:S = 0: GOTO 130
450 REM <CTRL-J><CTRL-J>GET LETTER<CTRL-J>
460 K = PEEK(Q): IF K < ASC("A") +128 OR K > ASC("Z") +128 THEN 460
470 POKE QQ,0
480 VTAB 21: HTAB 1: PRINT SPC( 12)
490 N = K -192:L$ = MID$ (A$,N,1)
500 REM <CTRL-J><CTRL-J>LETTER CORRECT?<CTRL-J>
510 FOR I = 1 TO LEN(W$): IF L$ < > MID$ (W$,I,1) THEN 600
520 VTAB 21: HTAB (2 *I) -7 +X: PRINT L$;:L = L +1
530 A(I) = 1
540 VTAB 21: HTAB 1: PRINT "ONE "Q$L$Q$"->";: IF L <2 THEN 570
550 VTAB 21: HTAB 1: PRINT " "
560 VTAB 21: HTAB 1: PRINT L;" ";L$;"'S!->"
570 POKE 0, INT( RND(1) *200) +20
580 POKE 1,80
590 CALL MU
600 NEXT : IF L = 0 THEN S = S +1
610 IF L < >0 THEN 330
620 REM <CTRL-J><CTRL-J>WRONG GUESS<CTRL-J>
630 VTAB 23: HTAB 1: PRINT "WRONG GUESSES:"
640 VTAB 23: HTAB Z +3: PRINT L$;" ":Z = Z +1: NORMAL
650 FOR J = 1 TO 40:SND = PEEK(MU +BZ): NEXT
660 ON S GOSUB 740,780,820,860,900,940,980,1020,1060,1100
670 VTAB 21: HTAB 1: PRINT "NO "Q$L$Q$"..."
680 GOTO 330
690 REM <CTRL-J><CTRL-J>GRAPHICS<CTRL-J>
700 COLOR= 5
710 HLIN X +6,X +13 AT 0: VLIN 0,39 AT X +13: HLIN X,X +13 AT 37: HLIN X,X +13 AT 38: PLOT X,39
720 PLOT X +9,1: PLOT X +10,2: PLOT X +11,3: PLOT X +12,4: RETURN
730 REM <CTRL-J><CTRL-J>ROPE<CTRL-J>
740 COLOR= 15
750 VLIN 1,5 AT X +6: VLIN 5,9 AT X +5: VLIN 5,9 AT X +7: PLOT X +6,9
760 RETURN
770 REM <CTRL-J><CTRL-J>HEAD<CTRL-J>
780 COLOR= 11
790 FOR I = 4 TO 7: HLIN X +4,X +8 AT I: NEXT : HLIN X +5,X +7 AT 3: HLIN X +5,X +7 AT 8
800 COLOR= 11: PLOT X +6,10: COLOR= 0: PLOT X +5,5: PLOT X +7,5: RETURN
810 REM <CTRL-J><CTRL-J>BODY<CTRL-J>
820 COLOR= 9
830 FOR I = 10 TO 18: HLIN X +4,X +8 AT I: NEXT
840 COLOR= 11: PLOT X +6,10: COLOR= 3: PLOT X +6,13: PLOT X +6,16: RETURN
850 REM <CTRL-J><CTRL-J>ARMS<CTRL-J>
860 COLOR= 9
870 VLIN 11,13 AT X +3: VLIN 11,13 AT X +9: VLIN 12,21 AT X +2: VLIN 12,21 AT X +10: RETURN
880 REM <CTRL-J><CTRL-J>LEGS<CTRL-J>
890 COLOR= 2
900 FOR I = 20 TO 32: HLIN X +4,X +8 AT I: NEXT : COLOR= 0: VLIN 23,32 AT X +6
910 COLOR= 11: VLIN 22,24 AT X +2: VLIN 22,24 AT X +10: PLOT X +1,24: PLOT X +11,24
920 COLOR= 8: HLIN X +4,X +8 AT 19
930 INVERSE : VTAB 24: HTAB 1: PRINT " ONE MORE MISS, AND YOU'RE HUNG! ";: NORMAL : RETURN
940 REM <CTRL-J><CTRL-J>BOOTS<CTRL-J>
950 COLOR= 8
960 FOR I = 29 TO 34: HLIN X +4,X +8 AT I: NEXT : FOR I = 33 TO 34: HLIN X +2,X +10 AT I: NEXT
970 COLOR= 0: VLIN 29,34 AT X +6: PLOT X +4,34: PLOT X +8,34
980 VTAB 24: HTAB 1: CALL -868
990 VTAB 24: HTAB 1: PRINT "YOU LOSE! IT'S ";: INVERSE : PRINT " ";W$;" ";: NORMAL : PRINT "!";
1000 FOR J = 1 TO 50:SND = PEEK(MU +BZ) - PEEK(MU +BZ) - PEEK(MU +BZ): NEXT
1010 GOTO 440
2540 POKE 0, INT( RND(1) *200) +20
2550 POKE 1,30
2560 CALL MU
2570 RETURN
2580 FOR I = 768 TO 789: READ J: POKE I,J: NEXT
2600 DIM L$(5),A$(30),X$(150),W$(21),A(20),N(255):Q = -16384:QQ = -16368:A$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ'-":U = -16336:Q$ = CHR$(34):MU = 771:BZ = -17107
2610 RETURN
8999 REM <CTRL-J><CTRL-J>COMPUTER'S WORDS<CTRL-J>
9000 N = INT( RND(1) *150) +1: IF N(N) THEN 9000
9010 N(N) = 1:W$ = X$(N): RETURN
9999 DATA 0,0,96,173,48,192,136,208,4,198,1,240,8,202,208,246,166,0,76,3,3,96
10000 DATA HAPPY NEW YEAR,ONE TWO THREE,PIE CRUST,SLOT MACHINE,HAM AND CHEESE,SCHOOL ZONE,DONALD DUCK,FOOTBALL,MEOW,MINNEAPOLIS
10010 DATA UNITED STATES,DICTIONARY,DICK TRACY,APPLE COMPUTER,CIGARETTE,E T PHONE HOME,ABRA CADABRA,FOOTBALL,QUICK DRAW,BEAGLE PUPPIES
10020 DATA CROAKING FROGS,LUGGAGE,FURNITURE,HAWAIIAN SURF,ZEBRA STRIPES,HOT DOG BUNS,NOSE JOB,PRIVATE EYE,LIGHT MY FIRE,SWEAT SHIRT
10030 DATA KITCHEN SINK,JUMBO JET,TELEVISION SET,TRAIN,KARATE EXPERT,SCREAMING KIDS,QUACKING DUCKS,CITY LIMITS,SYMBOL,POLICEMAN
10040 DATA BELLY BUTTON,ROLLAWAY BED,JACK AND JILL,HAUNTED HOUSE,HANDKERCHIEF,CINCINNATI,TIGHTROPE,JIGGLING,FREEWAY DRIVER,FOXY LADY
10050 DATA WONDER WOMAN,FOX TERRIER,BIG FAT PIG,ONION SOUP,EGGS OVER EASY,GOOD GRAVY,MISTLETOE,TAXICAB DRIVER,RED RIDINGHOOD,STAR WARS
10060 DATA ROLLING STONE,LAZY DAY,WALK THE PLANK,TAKE A CHANCE,SLAPSTICK,ROAST BEEF,FRANKENSTEIN,ONE MAN BAND,DOWNTOWN,CHICKEN SOUP
10070 DATA MOW THE LAWN,UMBRELLA,HIT A HOME RUN,GREASED PIG,BACON FAT,OATMEAL,YELLOW RIBBON,MICROWAVE OVEN,FROZEN CUSTARD,POPSCICLE
10080 DATA TEN SPEED BIKE,RADIO,POPULATION,STEREO,LUMBERJACK,FORTUNE COOKIE,BULLETIN BOARD,COWS GO MOO,WASHINGTON,YES SIR
10090 DATA GUNNY SACK,WATER FOUNTAIN,ORANGE PUMPKIN,SLIME,KEYBOARD,SOAPY WATER,JUICY PICKLES,HALF AN OUNCE,ORANGE JUICE,GOOD MOOD
10100 DATA RHYTHM,FLOPPY DISK,MEXICO,LIZARD,NOOSE,NEEDLE NOSE,KEYBOARD,SPLASH,ZOOLOGY,CRUNCH
10110 DATA CASSETTE,BOOKLET,PERFORATE,SHOWCASE,SPRAY,TOKYO,DECEMBER,LOLLIPOP,TURKEY,CAT TAIL
10120 DATA REAL ESTATE,COLLAPSE,SHOTGUN,FLEA POWDER,CRYBABY,OKLAHOMA,ALASKA,CIVIC,UNQUESTIONABLY,LIQUOR
10130 DATA QUAKER,JUMPY,FROWN,COLLAR,KNOBS,STOVE,SIGNATURE,SIX PACK,BEER KEG,SWEAT SHIRT
10140 DATA BUSY BODY,STRIPES,CALENDAR,PENCIL,COMMERCIAL,DITCH,SCOOPER,ARKANSAS,QUICKSAND,ROCKET SHIP
63900 NORMAL : TEXT : HOME : VTAB 10: PRINT "<M> MENU": PRINT "<C> CONTINUE THIS GAME": PRINT "<Q> QUIT": PRINT : PRINT "SELECT:";: GET W$: PRINT W$: IF W$ = "C" THEN POKE -16368,0: GOTO 130
63910 IF W$ = "M" THEN POKE 768,13: PRINT CHR$(4);"RUN SHORT MENU"
63920 IF W$ = "Q" THEN END
63930 GOTO 63900